Dark Paradise

Kód: Vybrat vše

sub YFish() 
var x,y,r,mx,my,rozsah,ryby,schovavani,pohyb,mluveni,zvuk,mapka
##################   ######################## 
#   Yaccobb's    #   #       Edit by        # 
#   extended     #   #   Carda and Castian  # 
# fishing script #   ######################## 
#     v1.5       # 
############################### 
##### nastaveni scriptu : ##### 
############################################################################### 
  rozsah=6 # ROZSAH RYBARENI 
# Tato hodnota je polovnou strany ctverce ve kterem budete rybarirt.          # 
# standardni hodnota : rozsah=3                                               # 
############################################################################### 
  ryby=5 # TYP SBIRANYCH RYB 
# Chceteli sbirat vsechny ryby, nastavte na hodnotu 1, pokud chete sbirat     # 
# pouze magicke ryby a mapy pokladu nastavte na hodnotu 5.                    # 
############################################################################### 
  pohyb=0 # AKTUALIZACE SOURADNIC 
# Chceteli pri pohybu aktualizovat souradnice(relativni pozice), nastavte     # 
# na 1, jinak(absolutni pozice) na 0. standard : pohyb=1                      # 
############################################################################### 
  schovavani=1 # HIDING ZAP/VYP 
# 1=zapnuto      0=vypnuto                                                    # 
############################################################################### 
  mluveni='resume' # 0=vypnuto 
# Skript se zastavi kdyz uvidite Serpentu nebo Krakena.                       # 
# Po napsani slova co zde napisete se script zase rozjede.                    # 
############################################################################### 
  zvuk=('C:\WINDOWS\Media\chord.wav') # 0=vypnuto 
  mapka=('C:\WINDOWS\Media\tada.wav') # 0=vypnuto 
# Zde nastavte zvuk ktery se prehraje kdyz chytite Serpentu nebo Krakena.     # 
# Mapka=zvuk pri vyloveni mapky. Nastavte 0 pro vynuti.                       # 
############################################################################### 
####### telo scriptu : ####### 
############################## 

dim tryby[8] 
dim bryby[8] 

tryby[1]=0x09CC # ryba 
tryby[2]=0x09CD # ryba 
tryby[3]=0x09CE # ryba 
tryby[4]=0x09CF # ryba 
tryby[5]=0x09CD # vzacna ryba 
tryby[6]=0x09CD # vzacna ryba 
tryby[7]=0x09CD # vzacna ryba 
tryby[8]=0x099B # mapka 

bryby[1]=0x0000 
bryby[2]=0x0000 
bryby[3]=0x0000 
bryby[4]=0x0000 
bryby[5]=0x0850 
bryby[6]=0x0482 
bryby[7]=0x084C 
bryby[8]=0x08A4 

mx = UO.GetX('self') 
my = UO.GetY('self') 
UO.DeleteJournal() 

UO.addobject('bag') 
UO.Print('Kam chces davat ryby?') 
While UO.Targeting() 
   wait(100) 
wend 

for x = -rozsah to rozsah 
for y = -rozsah to rozsah 

   if schovavani==1 then 
      while not UO.Hidden() 
         UO.Warmode('0') 
         UO.Print('Schovavam se...') 
         UO.UseSkill('Hiding') 
         UO.Deletejournal() 
         repeat 
            wait(100) 
         until UO.InJournal('hidden yourself|seem to hide') 
      wend 
   endif 

   UO.Print('Nyni chytam na ['+str(x)+', '+str(y)+']') 
   while UO.Count('0x0DBF') > 0 and not UO.InJournal('no fish here|location|in water')or UO.InJournal('far away') 
      UO.DeleteJournal() 
      if pohyb==1 then 
         mx = UO.GetX('self') 
         my = UO.GetY('self') 
      endif 
      wait(250) 
      UO.Waittargettile('1341', str(mx+x), str(my+y), '0') 
      UO.Usetype('0x0DBF') 
      UO.Deletejournal() 
      wait(500) 
      repeat 
         wait(100) 
      until UO.Injournal('You pull out|no fish here|location|far away|in water|You fish a while|Jeste nemuzes znovu nahodit|Targeting Cancelled|Unexpected target') 

      If UO.GetNotoriety(UO.JournalSerial(UO.InJournal(':')-1)) == 6 and NOT mluveni == 0 then 
         If NOT zvuk==0 then 
            uo.playwav(zvuk) 
         endif 
         repeat 
            wait(3000) 
         until (UO.JournalSerial(UO.InJournal(mluveni)-1) == UO.GetSerial('self')) 
      endif 
       
      If UO.InJournal('Vylovil si neco velmi zvlastniho') and NOT mapka==0 then 
         uo.playwav(mapka) 
      endif 

      if UO.InJournal('Jeste nemuzes znovu nahodit|That is too far away') then 
         wait(5000) 
      endif 

      if UO.InJournal('You pull') then 
         UO.SetReceivingContainer('bag') 
         for r = ryby to 8 
            UO.findtype(tryby[r],bryby[r],'ground') 
            if UO.FindCount() > 0 then 
               wait(200) 
               UO.grab ('0','finditem') 
               wait(200) 
            endif 
         next 
         UO.UnSetReceivingContainer() 
      endif 
   wend 
   UO.DeleteJournal() 
   If UO.Count('0x0DBF') < 1 then 
      UO.Print('Nemas vlasce!') 
      UO.FindType(0x0DBF,0x0979,'ground') 
      UO.MoveItem('finditem',-1,'self') 
      return 
   endif 
next 
next 

UO.Print("Rybareni ukonceno.") 

end sub